Question:

Question: I encountered a couple of problems while trying to model a wind tunnel test. The aim is to investigate the main rotor/ tail rotor/main rotor/tailplanes interactions and to validate this with wind tunnel data. I started to model the wind tunnel model with an "isolated rotor". This model works well. When initializing the trim analysis for an isolated rotor, one can select rotor forces/moments and TPP angles as trim target. However when I expanded the isolated rotor with added a horizontal tailplane to a 'rigid' body, the trim targets changed from "isolated rotor" trim targets to "free flight" trim conditions. When changing the rigid body to a constrained rigid body with all DOF's put to zero, no trim options are available ("no data entry").

Answer:

A constrained rigid body won't work for the trim problem. You need to use rigid body airframe and `free flight' model.

Question:

I already made a script file which runs an advance ratio trim sweep at a desired CT/sigma which works for the isolated rotor. Loading the model with fuselage data gives following error: can't read "isvarvaluesxamodeltrim-trmtar(HUBFX)": no such element in array

Answer:

It is due to an improper setting of trim targets.

Question:

How can I model a complete wind tunnel model with the trim options of an isolated rotor?

Answer:

The following file is for your reference:.
 

******************************************************

   *** Use the `user_init.exc' file to set customized trim options.

   You can edit a file named

        user_init.exc

    Just placing this file in your working directory should help set the trim variables and trim targets to what you desired.  The modifications may affect the xanalysis for other models.  So, just use them for your wind tunnel model.

************* File for your reference******************
//File: user_init.exc
//Desc: Example `user_init.exc' file to modify
//      default trim variable and target setting
//

//important to check if there is fuselage body

 isairframe = world_model_airframe_data_isairframe;
 isrotor1   = world_model_rotor1_rotor_data_isrotor1;
if (isairframe ==1 && isrotor1 ==1)
 //These are only default value for you to change from GUI
 pushg(world_analysis_trimtest)
      mytrimbias = [6000 0 0]' //6000 thrust, zero cyclic flapping;
      mytrimperturb = [0.01 0.01 0.01]'  //for swashplate angle;
 popg
 //for trimvariable screen entry
 pushg(world_analysis_trimtest_trimvariable)
    //reset the trimvariable varlist (clear)
    varlist @trimvariable + []
    theta0 = &world_data_theta1   "Swashplate collctive angle (rad)";
    thetac = &world_data_a1s1     "Swashplate cyclic (cosine) angle (rad)";
    thetas = &world_data_b1s1     "Swashplate cyclic (sine) angle (rad)";
    varlist @trimvariable + theta0, thetac, thetas
    pushg(world_analysis_trimtest_trimvariable_select)
       //reset default selection
       //two Euler angle (previously have been selected as trimvariables
       phi  =  0; theta =0;
       //set swashplate as trimvariables
       theta0=1; thetac=1; thetas=1;
    popg
 popg
 //reset trim perturbation size
 pushg(world_analysis_trimtest_trimvarptb)
     varlist @trimvarptb + [];
     //new value
     theta0 = &trimtest_mytrimperturb(1) "Swashplate collctive angle (rad)";
     thetac = &trimtest_mytrimperturb(2) "Swashplate cyclic (cos) angle (rad)";
     thetas = &trimtest_mytrimperturb(3) "Swashplate cyclic (sin) angle (rad)";
     varlist @trimvarptb + theta0, thetac, thetas
 popg
 //
 //for `trimtarget' screen  display
 pushg(world_analysis_trimtest_trimtarget)
      hubfz =& world_model_rotor1_rotor_cpg_out_thubf(3) "Rotor Z-force [lbs]";
      betac =& world_model_rotor1_rotor_cpg_out_tippa(2) ..
               "TPP cyclic (cosine) tilt angle (rad)";
      betas =& world_model_rotor1_rotor_cpg_out_tippa(3) ..
               "TPP cyclic (sine) tilt angle (rad)";

      //set default selection 1: selected;
      pushg(world_analysis_trimtest_trimtarget_select)
             //deselect those with body dof
             vxbd   = 0; vybd =0; vzbd = 0; pd = 0; qd=0; phid=0;
             //reset trimtarget varlist
             varlist @trimtarget + [];
             //add what user defined
             hubfz=1; betac=1; betas=1;
             varlist @trimtarget + trimtest_trimtarget_hubfz
             varlist @trimtarget + trimtest_trimtarget_betac
             varlist @trimtarget + trimtest_trimtarget_betas
      popg
      //default trim bias (target value)
      pushg(world_analysis_trimtest_trimbias)
            hubfz   =& world_analysis_trimtest_mytrimbias(1) ..
                       "Rotor Z-force (lbs) ";
            betac   =& world_analysis_trimtest_mytrimbias(2)  ..
                       "TPP Cyclic (cosine) tilt angle (rad)";
            betas   =& world_analysis_trimtest_mytrimbias(3)  ..
                        "TPP Cyclic (sine) tilt angle (rad)";
                varlist @trimbias + [];
                varlist @trimbias + hubfz, betac, betas
      popg
      //default trim tolerance
      pushg(world_analysis_trimtest_trimtol)
         hubfz   = &world_cpg_tol(13) "Rotor Z-force (lbs) ";
         betac   = &world_cpg_tol(18) "TPP Cyclic (cosine) tilt angle (rad)";
         betas   = &world_cpg_tol(19) "TPP Cyclic (sine) tilt angle (rad)";
                varlist @trimtol  + [];
                varlist @trimtol + hubfz, betac, betas
      popg
  popg
end
//EOF